10 REM LM565DES.BAS
15 CLS : PI=3.14159
20 PRINT" A PROGRAM TO DESIGN A PHASE LOCK LOOP USING THE LM565 IC"
30 PRINT" WRITTEN BY RUSS KINCAID, 18 JUNE 1999" : PRINT
40 PRINT"THIS IS A TYPE 1 SERVO, IT HAS PHASE ERROR THAT INCREASES"
50 PRINT"AS THE FREQUENCY DEVIATES FROM CENTER" : PRINT
60 PRINT"THE DEMODULATOR OUTPUT IS 3.6K OHMS, SO IT NEEDS TO BE BUFFERED"
70 PRINT
80 INPUT"WHAT IS THE TOTAL SUPPLY VOLTAGE ";VC
90 INPUT"WHAT IS THE CENTER FREQUENCY IN HZ (300KHZ/MIL 250KHZ/COM MAX) ";FO
100 PRINT:PRINT"THE MAX HOLD IN RANGE IS: ";8*FO/VC;" HZ"
105 KOKD = 33.6*FO/VC
107 R1=3600
110 PRINT:REM FO=0.3/RO/CO
112 PRINT"CHOOSE THE OSCILLATOR RESISTOR (RO) TO BE BETWEEN 2K & 20K ";
114 INPUT RO
116 CO=.3/RO/FO : PRINT "OSCILLATOR CAP. (CO) = ";CO
118 INPUT"TRY ANOTHER VALUE FOR RO Y OR N ";Y$
119 IF LEFT$(Y$,1)="y" OR LEFT$(Y$,1)="Y" THEN 112
120 INPUT"WHAT IS THE CLOSED LOOP BANDWIDTH TO BE DESIGNED (HZ) ";BW
130 PRINT "YOU MAY SPECIFY THE DAMPING FACTOR, 0.5 WILL GIVE SOME OVERSHOOT,"
140 PRINT"1.0 IS OPTIMUM AND MORE THAN 1 WILL SLOW THE RESPONSE"
150 INPUT"WHAT VALUE ";ZETA
160 REM THE OPEN LOOP GAIN IS: K=33.6*FO/VC
170 K=33.6*FO/VC
180 C1=(1/R1)*(KOKD/4/PI^2/BW^2-ZETA/PI/BW)
190 REM T2=R2*C1 = ZETA/PI/BW  AND T3=R1*C2 <T2<<T1
200 R2 = ZETA/PI/BW/C1 : C2 = R2*C1/10/R1
210 PRINT:PRINT
220 PRINT TAB(20);"OUTPUT DATA"
225 PRINT"RO = ";RO,"CO = ";CO
230 PRINT"C1 = ";C1;" FARADS"
240 PRINT"C2 = ";C2;" FARADS"
250 PRINT"R2 = ";R2;" OHMS"
270 PRINT"CLOSED LOOP BANDWIDTH = ";BW;" HZ"
280 PRINT"LOCK RANGE = ";8*FO/VC;" HZ"
290 PRINT: PRINT"THIS IS THE CIRCUIT:"
300 PRINT
305 PRINT"                    _____________"
310 PRINT"              -VDD--|1        14|--NC"
320 PRINT"REF FREQ------------|2        13|--NC"
330 PRINT"INPUT---------------|3        12|--NC"
340 PRINT"              |-----|4        11|--NC"
350 PRINT"              |-----|5        10|-----------|-- +VCC"
360 PRINT"OUTPUT DC REF-------|6         9|--CO--GND  |"
370 PRINT"DEMOD OUT  |---|----|7         8|-----RO----|"
380 PRINT"           C2  R2 | -----------   |"
390 PRINT"           |   |  |----.001UF-----|"
400 PRINT"         GND   C1"
410 PRINT"               |"
420 PRINT"              GND"
434 INPUT"MODIFY DESIGN ";Y$
436 IF LEFT$(Y$,1)="y" OR LEFT$(Y$,1)="Y" THEN CLS:GOTO 80
438 INPUT"HARDCOPY ";Y$
440 IF LEFT$(Y$,1)="y" OR LEFT$(Y$,1)="Y" THEN 450 ELSE END
450 OPEN "PRN" FOR OUTPUT AS #1
460 PRINT#1,:PRINT#1,
470 PRINT#1, TAB(20);"OUTPUT DATA"
474 PRINT#1,"RO = ";RO;" OHMS
476 PRINT#1,"CO = ";CO;" FARADS"
480 PRINT#1,"C1 = ";C1;" FARADS"
490 PRINT#1,"C2 = ";C2;" FARADS"
500 PRINT#1,"R2 = ";R2;" OHMS"
510 PRINT#1,"CLOSED LOOP BANDWIDTH = ";BW;" HZ","DAMPING FACTOR = ";ZETA
520 PRINT#1,"LOCK RANGE = ";8*FO/VC;" HZ"
530 PRINT#1,: PRINT#1,"THIS IS THE CIRCUIT:"
540 PRINT#1,
550 PRINT#1,"                    _____________"
560 PRINT#1,"              -VDD--|1        14|--NC"
570 PRINT#1,"REF FREQ------------|2  LM    13|--NC"
580 PRINT#1,"INPUT---------------|3  565   12|--NC"
590 PRINT#1,"   SQ WAVE OUT|-----|4        11|--NC"
600 PRINT#1,"              |-----|5        10|-----------|-- +VCC"
610 PRINT#1,"OUTPUT DC REF-------|6         9|--CO-GND   |"
620 PRINT#1,"DEMOD OUT  |---|----|7_________8|-----RO----|"
630 PRINT#1,"           C2  R2 |               |"
640 PRINT#1,"           |   |  |----.001UF-----|"
650 PRINT#1,"         GND   C1"
660 PRINT#1,"               |"
670 PRINT#1,"              GND"
680 PRINT#1,:PRINT#1,:PRINT#1,"DEMOD SENSITIVITY (VOLTS/RADIAN) = 0.68"
690 PRINT#1,"VCO SENSITIVITY = ";33.6*FO/VC/.68;" RADIANS/SEC/VOLT"
700 PRINT#1,"INPUT IMPEDANCE = 5K OHMS"
710 PRINT#1,"INPUT LEVEL FOR GOOD PERFORMANCE: 10mV TO 100mV"
720 PRINT#1,"DEMOD OUTPUT RESISTANCE IS 3.6K AND SHOULD BE BUFFERED"
730 PRINT#1,"PINS 6 & 7 OUTPUT COMMON MODE VOLTAGE = 4.5 VOLTS"
740 PRINT#1,"SQUARE WAVE OUTPUT (PIN 4) IMPEDANCE = 5K OHMS"
750 PRINT#1,"TRIANGLE OUTPUT (PIN 9) AMPLITUDE = 2.4 VOLTS P/P NOMINAL"
760 PRINT#1,".001uF BETWEEN PINS 7&8 IS REQUIRED TO PREVENT OSCILLATION"
765 PRINT#1,CHR$(12)
770 CLOSE#1
775 CHAIN "C:\AUTOMENU\DESNMENU"
780 REM LM565DES.BAS
790 END