10  REM 78S40DES.BAS
20 REM WRITTEN BY RUSS KINCAID 15 SEPT 1999 REVISED 17 DEC 2002
30 REM BASED ON NATIONAL SEMI APPLICATION NOTE: AN-711
40 REM
50 WIRE$(1)="27" : WIRE$(2)="22"
60 CLS:PRINT"THIS PROGRAM DESIGNS A SWITCHING REGULATOR USING THE NATIONAL"
70 PRINT"SEMICONDUCTOR IC: LM78S40"
80 PRINT:PRINT"YOU WILL NEED TO SPECIFY:"
90 PRINT TAB(10);"1.  INPUT VOLTAGE"
100 PRINT TAB(10);"2.  OUTPUT VOLTAGE"
110 PRINT TAB(10);"3.  OUTPUT CURRENT"
120 PRINT TAB(10);"4.  ALLOWABLE RIPPLE"
130 PRINT TAB(10);"5.  SWITCHING FREQUENCY WILL BE 30 kHz UNLESS YOU SPECIFY"
140 PRINT:PRINT"YOU WILL HAVE TO USE EXTERNAL COMPONENTS FOR VOLTAGES GREATER"
150 PRINT"THAN 30 VOLTS AND CURRENT GREATER THAN 1 AMP, OR NEGATIVE OUTPUT."
160 PRINT
170 INPUT"WHAT IS THE DC INPUT VOLTAGE";VIN
180 IF VIN<3 THEN PRINT"THE INPUT VOLTAGE MUST BE + 3 VOLTS OR MORE":PRINT"YOU MUST RESTATE THE INPUT AND OUTPUT VOLTAGES":GOTO 170
190 IF VIN>40 THEN PRINT"THE IC CANNOT TAKE MORE THAN 40 VOLTS VIN RELATIVE TO GND"
200 INPUT"WHAT IS THE DC OUTPUT VOLTAGE";VOUT
210 INPUT"WHAT IS THE LOAD CURRENT (AMPS)";IL
220 IF IL>1.5 THEN PRINT"THE INTERNAL DIODE CANNOT HANDLE MORE THAN 1.5 AMPS.  yOU MAY USE AN EXTERNAL DIODE"
230 INPUT"HOW MUCH OUTPUT RIPPLE (IN VOLTS)";VRIPPLE
240 INPUT"WILL YOU SPECIFY THE SWITCHING FREQUENCY Y OR N";Y$
250 F=30000!
260 IF LEFT$(Y$,1)="N" OR LEFT$(Y$,1)="n" THEN 280
270 INPUT"WHAT IS THE SWITCHING FREQ .10<F>100 kHz";F:F=F*1000!
280 IF VOUT<VIN AND VOUT>1.3 THEN 1470
290 IF VOUT<1.3 AND VOUT>0 THEN PRINT"YOU CAN DO THIS BUT FEEDBACK IS MODIFIED":LOWV=1 :GOTO 1470
300 IF VOUT>VIN AND VOUT<40 THEN 800
310 IF VOUT<0 THEN 2760
320 IF VIN<3 THEN PRINT"THIS PROGRAM ASUMES THAT VIN IS POSITIVE RELATIVE TO GND":PRINT"YOU MUST RESTATE THE INPUT AND OUTPUT VOLTAGES":GOTO 170
330 IF VIN>40 THEN PRINT"THE IC CANNOT TAKE MORE THAN 40 VOLTS VIN RELATIVE TO GND"
340 IF VOUT > 40 OR VOUT >VIN THEN 370
350 PRINT"UNKNOWN PROBLEM (BUG) CALL AUTHOR":STOP
360 REM BOOST CIRCUIT FOR OVER 40V OR OVER 1.5AMP OR OVER VIN
370 HI=1:IPK=2*IL*(VOUT+1-.6)/(VIN-.6)
380 GOTO 820
390 IF IPK/20+1/R3>1.5 THEN PRINT#1,"YOU NEED A DARLINGTON TRANSISTOR":GOTO 410
400 R4=(VIN-2)/(IPK/20+1/R3):GOTO 440
410 IPK=2*IL*(VOUT)/(VIN-1)
420 R4=(VIN-2.5)/(IPK/100+1.5/R3)
430 IF IPK>1.5 THEN PRINT"use external diode rated";IPK;" AMPS"
440 PRINT#1,"R4 = ";R4;" OHMS"
450 PRINT:PRINT#1,"CIRCUIT SCHEMATIC:"
452 PRINT#1,"BYPASS PIN 8 TO GROUND WITH 0.1uF FOR STABILITY"
460 PRINT#1,
470 PRINT#1,"VIN----------|-RSC-------|----------|--L-----------|"
480 PRINT#1,"             |           |          |              |"
490 PRINT#1," |--------|  |           |          |              |"
500 PRINT#1," |  |--|  |  |  |-CT-GND |          R4             |"
510 PRINT#1," |  |  |  |  |  |        |  GND     |------|       |"
520 PRINT#1," |  | _|__|__|__|________|___|______|______|__     |"
530 PRINT#1," |  | |9 10  13 12       14  11     15     16 |    |"
540 PRINT#1," |  | |                                       |    |"
550 PRINT#1," |  | |        LM78S40                        |    |"
560 PRINT#1," |  | |                                       |    |"
570 PRINT#1," |  | |__8_____________________3___1___2______|    |"
580 PRINT#1," |  |    |                     |                   |"
590 PRINT#1," |  |----|                     |       |-----------|"
600 PRINT#1," |                             |     |/`c          |"
610 PRINT#1," |             GND-----R3------|-----|             A"
620 PRINT#1," |                                   |\e___GND   DIODE"
630 PRINT#1," |                                                 K"
640 PRINT#1," |-------------R1--------------|-------------------|-----OUT"
650 PRINT#1," R2                            CO"    
660 PRINT#1," |                             |"
670 PRINT#1,"GND                           GND"
680 MILLIJOULES=(N*IPK)^2*AL(J)*.000001
690 PRINT#1,
700 PRINT#1,"FOR TRANSISTOR & DIODE SELECTION, CONSIDER PEAK CURRENT = ";IPK
710 GOTO 780: PRINT#1,:PRINT#1,"TOROID INDUCTOR DESIGN:"
720 REM PRINT#1,"TECH AMERICA PART NUMBER: ";CORE$(J)
730 REM PRINT#1,"CORE SIZE: ";SIZE$(J);" INCHES ODxIDxH"
740 REMPRINT#1,"NUMBER OF TURNS: ";N
750 REM PRINT#1,"WIRE #";WIRE$(Q);" SHOULD FIT, USE AS LARGE AS PRACTICAL"
760 PRINT#1,"STORED ENERGY IS : ";MILLIJOULES;" MILLIJOULES"
770 PRINT#1, CHR$(12)
780 CLOSE#1 : GOTO 3830
790 REM BOOST CIRCUIT
800 IPK=2*IL*(VOUT+.8)/(VIN-.45)
810 IF IPK>1.5 THEN 370
820 RSC=.3/IPK
830 K=(VOUT+1.25-VIN)/(VIN-.45)
840 TOFF=1/F/(K+1)
850 TON=(VOUT+.8)/(VIN-.45)*TOFF:PRINT"TON=";TON,"TOFF=";TOFF:PRINT
860 CT=TOFF*.00045:PRINT"CT = ";CT/1E-12;"pF CHOOSE A STANDARD VALUE:"
870 INPUT"STANDARD VALUE FOR CT (pF) ";CT:CT=CT*1E-12:TOFF=CT/.00045
880 L=TOFF*(VOUT+1.25-VIN)/IPK
890 IF L<0 THEN PRINT"L= ";L:STOP
900 CO=IPK/F/8/VRIPPLE
910 PRINT"CO = ";CO/.000001;" uF, CHOOSE A STANDARD VALUE:"
920 INPUT"STANDARD VALUE FOR CO IN uF ";CO:CO=CO/.000001
930 PRINT:PRINT"YOU MAY CHOOSE THE CURRENT IN THE FEEDBACK RESISTOR"
940 PRINT"THE VALUE MUST BE > .1mA, 1mA IS SUGGESTED"
950 INPUT"FEEDBACK CURRENT IN mA ";FI:FI=FI/1000
960 R2=1.245/FI
970 PRINT"R2 = ";R2;" OHMS, CHOOSE A STANDARD VALUE:"
980 INPUT"STANDARD VALUE FOR R2: ";R2
990 R1=VOUT/FI-R2
1000 R3 = 20*(VIN-1.3)/IPK
1010 REM END OF BOOST DESIGN, GOTO INDUCTOR DESIGN
1020 GOSUB 3520
1030 OPEN "PRN" FOR OUTPUT AS #1
1040 PRINT#1,"LM78S40 BOOST CIRCUIT FOR VOUT UNDER 40 VOLTS";TAB(30);DATE$
1050 PRINT:PRINT#1,"INPUT VOLTS = ";VIN
1060 PRINT#1,"OUTPUT VOLTS = ";VOUT
1070 PRINT#1,"OUTPUT RIPPLE = ";VRIPPLE;" MAX"
1080 PRINT#1,"MAX LOAD CURRENT = ";IL
1090 PRINT:PRINT#1,"CIRCUIT VALUES:"
1100 PRINT#1,"R1 = ";R1;" OHMS.  THIS WILL NEED TRIMMING"
1110 PRINT#1,"R2 = ";R2;" OHMS"
1120 PRINT#1,"R3 = ";R3;" OHMS"
1130 PRINT#1,"RSC = ";RSC;" OHMS"
1140 PRINT#1,"CO = ";CO/1000000!;" uF"
1150 PRINT#1,"CT = ";CT/1E-12;" pF"
1160 PRINT#1,"L = ";L*1000000!;" uH, CHOOSE THE NEAREST STANDARD VALUE"
1170 IF HI=1 THEN GOTO 390
1180 PRINT:PRINT#1,"CIRCUIT SCHEMATIC:"
1182 PRINT#1,"BYPASS PIN 8 TO GROUND WITH 0.1uF FOR STABILITY"
1190 PRINT#1,
1200 PRINT#1,"VIN----------|-RSC-------|----------|--L---|-----|"
1210 PRINT#1,"             |           |          |      |     |"
1220 PRINT#1," |--------|  |           |          |      |     |"
1230 PRINT#1," |  |--|  |  |  |-CT-GND |          R3     |     |"
1240 PRINT#1," |  |  |  |  |  |        |  GND     |      |     |"
1250 PRINT#1," |  | _|__|__|__|________|___|______|______|__   |"
1260 PRINT#1," |  | |9 10  13 12       14  11     15     16 |  |"
1270 PRINT#1," |  | |                                       |  |"
1280 PRINT#1," |  | |        LM78S40                        |  |"
1290 PRINT#1," |  | |                                       |  |"
1300 PRINT#1," |  | |__8_____________________3___1___2______|  |"
1310 PRINT#1," |  |    |                     |   |   |         |"
1320 PRINT#1," |  |----|                    GND  |   |---------|"
1330 PRINT#1," |-------------R1------------------|---------------OUT"
1340 PRINT#1," R2                                CO"
1350 PRINT#1," |                                 |"
1360 PRINT#1,"GND                               GND"
1370 GOTO 1450: MILLIJOULES=(N*IPK)^2*AL(J)*.000001
1380 PRINT:PRINT#1,"TOROID INDUCTOR DESIGN:"
1390 PRINT#1,"TECH AMERICA PART NUMBER: ";CORE$(J)
1400 PRINT#1,"CORE SIZE: ";SIZE$(J);" INCHES ODxIDxH"
1410 PRINT#1,"NUMBER OF TURNS: ";N
1420 PRINT#1,"WIRE #";WIRE$(Q);" SHOULD FIT, USE AS LARGE AS PRACTICAL"
1430 PRINT#1,"STORED ENERGY IS : ";MILLIJOULES;" MILLIJOULES"
1440 PRINT#1, CHR$(12)
1450 CLOSE#1 : GOTO 3830
1460 REM BUCK CIRCUIT
1470 IPK=2*IL
1480 RSC=.33/IPK
1490 VSAT=1.1/IPK:DIODEV=1.25/IPK
1500 IF IPK<=1.5 THEN 1630
1510 PRINT :PRINT:REM BUCK CIRCUIT FOR CURRENT GREATER THAN 1.5AMPS
1520 PRINT"YOU WILL NEED AN EXTERNAL TRANSISTOR AND DIODE CAPABLE OF ";IPK;" AMPS"
1530 PRINT"WHAT IS THE DIODE DROP AT ";IPK;" AMPS";:INPUT DIODEV
1540 PRINT"WHAT IS THE SATURATED HFE OF THE TRANSISTOR?"
1542 PRINT"HINT:  FOR A SINGLE PNP TRANSISTOR USE HFE(SAT) OF 10 TO 20"
1544 PRINT"FOR A DARLINGTON, USE HFE(SAT) OF 100 TO 200"
1546 PRINT"FOR A P TYPE ENHANCMENT MODE FET USE 10 TO 20 FOR FASTEST RESPONSE"
1548 INPUT"HFE(SAT) = ",HFESAT
1550 PRINT"WHAT IS THE V(SAT) OF THE TRANSISTOR AT ";IPK;" AMPS";:INPUT VSAT
1590 INPUT"WHAT IS THE VBE(SAT) OR V(ON) ";VBESAT
1600 R4=(HFESAT/IPK)*(VIN-.33-VBESAT)
1610 IF R4<0 THEN PRINT"YOUR INPUT VOLTAGE IS TOO LOW":GOTO 3820
1620 R3=R4*2
1630 K=(VOUT+DIODEV)/(VIN-VSAT-VOUT)
1640 TOFF=1/F/(K+1)
1650 TON=K*TOFF
1660 CT=TOFF*.00045:PRINT"CT = ";CT/.000001;"UF CHOOSE A STANDARD VALUE:"
1670 INPUT"STANDARD VALUE FOR CT (UF) ";CT:CT=CT*.000001:TOFF=CT/.00045
1680 L=(VOUT+DIODEV)/IPK*TOFF:PRINT:PRINT"L = ";L
1690 CO=IPK/F/8/VRIPPLE
1700 PRINT"CO = ";CO/.000001;" uF, CHOOSE A STANDARD VALUE:"
1710 INPUT"STANDARD VALUE FOR CO IN uF ";CO:CO=CO/.000001
1720 PRINT:PRINT"YOU MAY CHOOSE THE CURRENT IN THE FEEDBACK RESISTOR"
1730 PRINT"THE VALUE MUST BE > .1mA, 1mA IS SUGGESTED"
1740 INPUT"FEEDBACK CURRENT IN mA ";FI:FI=FI/1000
1750 R2=1.245/FI
1760 PRINT"R2 = ";R2;" OHMS, CHOOSE A STANDARD VALUE:"
1770 INPUT"STANDARD VALUE FOR R2: ";R2
1780 IF LOWV=1 THEN R1=(1.3-VOUT)/FI:GOTO 1810
1790 R1=VOUT/FI-R2
1800 REM THERE IS NO R3 IN THIS CKT
1810 GOSUB 3520
1820 OPEN "PRN" FOR OUTPUT AS #1
1830 PRINT#1,"LM78S40 BUCK  CIRCUIT";TAB(30);DATE$
1840 PRINT:PRINT#1,"INPUT VOLTS = ";VIN
1850 PRINT#1,"OUTPUT VOLTS = ";VOUT
1860 PRINT#1,"OUTPUT RIPPLE = ";VRIPPLE;" MAX"
1870 PRINT#1,"MAX LOAD CURRENT = ";IL
1880 PRINT:PRINT#1,"CIRCUIT VALUES:"
1890 PRINT#1,"R1 = ";R1;" OHMS.  THIS WILL NEED TRIMMING"
1900 PRINT#1,"R2 = ";R2;" OHMS"
1910 PRINT#1,"RSC = ";RSC;" OHMS"
1920 PRINT#1,"CO = ";CO/1000000!;" uF"
1930 PRINT#1,"CT = ";CT/.000001;" uF"
1940 PRINT#1,"L = ";L*1000000!;" uH, CHOOSE THE NEAREST STANDARD VALUE"
1950 IF IPK>1.5 THEN GOSUB 2380
1960 PRINT:PRINT#1,"CIRCUIT SCHEMATIC:"
1962 PRINT#1,"BYPASS PIN 8 TO GROUND WITH 0.1uF FOR STABILITY"
1970 PRINT
1980 PRINT#1,"VIN----------|-RSC-------|----------|------|"
1990 PRINT#1,"             |           |          |      |"
2000 PRINT#1," |--------|  |           |          |      |"
2010 PRINT#1," |  |--|  |  |  |-CT-GND |          |      |"
2020 PRINT#1," |  |  |  |  |  |        |  GND     |      |"
2030 PRINT#1," |  | _|__|__|__|________|___|______|______|__ "
2040 PRINT#1," |  | |9 10  13 12       14  11     15     16 |"
2050 PRINT#1," |  | |                                       |"
2060 PRINT#1," |  | |        LM78S40                        |"
2070 PRINT#1," |  | |                                       |"
2080 PRINT#1," |  | |__8_________________________3___1___2__|"
2090 PRINT#1," |  |    |                         |   |   |   "
2100 IF LOWV=1 THEN 2150
2110 PRINT#1," |  |----|                         |---|   GND"
2120 PRINT#1," |                                 L"
2130 PRINT#1," |-------------R1------------------|---------------+OUT"
2140 GOTO 2250
2150 PRINT#1," |  |-R1-|                         |---|   GND"
2160 PRINT#1," |  |                              L"
2170 PRINT#1," |  R2                             |"
2180 PRINT#1," |  |                              |"
2190 PRINT#1," | GND                             |"
2200 PRINT#1," |---------------------------------|----------------+OUT"
2210 PRINT#1,"                                   CO"
2220 PRINT#1,"                                   |"
2230 PRINT#1,"                                  GND"
2240 GOTO 2280
2250 PRINT#1," R2                                CO"
2260 PRINT#1," |                                 |"
2270 PRINT#1,"GND                               GND"
2280 GOTO 2370: MILLIJOULES=(N*IPK)^2*AL(J)*.000001
2290 PRINT#1,
2300 PRINT:PRINT#1,"TOROID INDUCTOR DESIGN:"
2310 PRINT#1,"TECH AMERICA PART NUMBER: ";CORE$(J)
2320 PRINT#1,"CORE SIZE: ";SIZE$(J);" INCHES ODxIDxH"
2330 PRINT#1,"NUMBER OF TURNS: ";N
2340 PRINT#1,"WIRE #";WIRE$(Q);" SHOULD FIT, USE AS LARGE AS PRACTICAL"
2350 PRINT#1,"STORED ENERGY IS : ";MILLIJOULES;" MILLIJOULES" 
2360 PRINT#1, CHR$(12)
2370 CLOSE#1 : GOTO 3830
2380 PRINT#1,"R3 = ";R3;" OHMS":PRINT#1,"R4 = ";R4;" OHMS"
2390 PRINT:PRINT#1,"CIRCUIT SCHEMATIC:"
2392 PRINT#1,"BYPASS PIN 8 TO GROUND WITH 0.1uF FOR STABILITY"
2400 PRINT
2410 PRINT#1,"                           e PNP c"
2420 PRINT#1,"                         |-\_____/-----------------|----|"
2430 PRINT#1,"                         |    |                    |    |"
2440 PRINT#1,"VIN----------|-RSC-------|-R3-|--R4-|------|       |    k"
2450 PRINT#1,"             |           |          |      |       L   DIODE"
2460 PRINT#1," |--------|  |           |          |      |       |    a"
2470 PRINT#1," |  |--|  |  |  |-CT-GND |          |      |       |    |"
2480 PRINT#1," |  |  |  |  |  |        |  GND     |      |       |   GND"
2490 PRINT#1," |  | _|__|__|__|________|___|______|______|__     |"
2500 PRINT#1," |  | |9 10  13 12       14  11     15     16 |    |"
2510 PRINT#1," |  | |                                       |    |"
2520 PRINT#1," |  | |        LM78S40                        |    |"
2530 PRINT#1," |  | |                                       |    |"
2540 PRINT#1," |  | |__8_________________________3___1___2__|    |"
2550 PRINT#1," |  |    |                         |   |   |       |"
2560 IF LOWV=1 THEN 2610
2570 PRINT#1," |  |----|                        GND              |"
2580 PRINT#1," |                                                 |"
2590 PRINT#1," |-------------R1----------------------------------|---+OUT"
2600 GOTO 2710
2610 PRINT#1," |  |-R1-|                        GND              |"
2620 PRINT#1," |  |                                              |"
2630 PRINT#1," |  R2                                             |"
2640 PRINT#1," |  |                                              |"
2650 PRINT#1," | GND                                             |"
2660 PRINT#1," |---------------------------------|---------------+OUT"
2670 PRINT#1,"                                   CO"
2680 PRINT#1,"                                   |"
2690 PRINT#1,"                                  GND"
2700 GOTO 2740
2710 PRINT#1," R2                                               CO"
2720 PRINT#1," |                                                 |"
2730 PRINT#1,"GND                                               GND"
2740     RETURN 2280
2750 REM NEGATIVE (INVERTING) CIRCUIT
2760 CLS
2770 PRINT"YOU WILL NEED AN EXTERNAL PNP TRANSISTOR AND EXTERNAL DIODE RATED"
2780 PRINT"FOR THE VOLTAGE AND CURRENT AT THE OUTPUT."
2790 INPUT"WHAT IS THE COLLECTOR SATURATION VOLTAGE AT 2 TIMES I OUT";VSAT
2800 INPUT"WHAT IS THE DIODE DROP AT 2 TIMES I OUT ";VD
2810 INPUT"WHAT IS THE SATURATED BETA OF THE PNP (SUGGEST 20) ";BETA
2820 INPUT"WHAT IS THE SATURATED BASE TO EMITTER VOLTAGE (SUGGEST 1V) ";VBE
2830 IPK=2*(VIN+VD-VOUT-VSAT)/(VIN-VSAT)
2840 RSC=.3/IPK
2850 K=(VD-VOUT)/(VIN-VSAT)
2860 TOFF=1/F/(K+1)
2870 TON=K*TOFF
2880 CT=TOFF*.00045:PRINT"CT = ";CT/1E-12;"pF CHOOSE A STANDARD VALUE:"
2890 INPUT"STANDARD VALUE FOR CT (pF) ";CT:CT=CT*1E-12:TOFF=CT/.00045
2900 L=(VD-VOUT)/IPK*TOFF
2910 CO=IPK/F/8/VRIPPLE
2920 PRINT"CO = ";CO/.000001;" uF, CHOOSE A STANDARD VALUE:"
2930 INPUT"STANDARD VALUE FOR CO IN uF ";CO:CO=CO/.000001
2940 PRINT:PRINT"YOU MAY CHOOSE THE CURRENT IN THE FEEDBACK RESISTOR"
2950 PRINT"THE VALUE MUST BE > .1mA, 1mA IS SUGGESTED"
2960 INPUT"FEEDBACK CURRENT IN mA ";FI:FI=FI/1000
2970 R2=1.245/FI
2980 PRINT"R2 = ";R2;" OHMS, CHOOSE A STANDARD VALUE:"
2990 INPUT"STANDARD VALUE FOR R2: ";R2
3000 R1=-VOUT/FI-R2
3010 R3=100
3020 R4=(VIN-.3-1.3-VBE)/(VBE/R3+IPK/BETA)
3030 GOSUB 3520
3040 OPEN "PRN" FOR OUTPUT AS #1
3050 PRINT#1,"LM78S40 NEGATIVE OUTPUT CIRCUIT";TAB(50);DATE$
3060 PRINT:PRINT#1,"INPUT VOLTS = ";VIN
3070 PRINT#1,"OUTPUT VOLTS = ";VOUT
3080 PRINT#1,"OUTPUT RIPPLE = ";VRIPPLE;" MAX"
3090 PRINT#1,"MAX LOAD CURRENT = ";IL
3100 PRINT:PRINT#1,"CIRCUIT VALUES:"
3110 PRINT#1,"R1 = ";R1;" OHMS.  THIS WILL NEED TRIMMING"
3120 PRINT#1,"R2 = ";R2;" OHMS"
3130 PRINT#1,"R3 = ";R3;" OHMS"
3140 PRINT#1,"R4 = ";R4;" OHMS"
3150 PRINT#1,"RSC = ";RSC;" OHMS"
3160 PRINT#1,"CO = ";CO/1000000!;" uF"
3170 PRINT#1,"CT = ";CT*1E+12;" pF"
3180 PRINT#1,"L = ";L*1000000!;" uH, CHOOSE THE NEAREST STANDARD VALUE"
3190 PRINT:PRINT#1,"CIRCUIT SCHEMATIC:"
3192 PRINT#1,"BYPASS PIN 8 TO GROUND WITH 0.1uF FOR STABILITY"
3200 PRINT#1,"                            PNP TRANSISTOR"
3210 PRINT#1,"                          _e    c___________________L__GND"
3220 PRINT#1,"                         | _\___/_                |"
3230 PRINT#1,"                         |    |                   | "
3240 PRINT#1,"VIN----------|-RSC-------|-R3-|--R4-|------|      | "
3250 PRINT#1,"             |           |          |      |      |"
3260 PRINT#1," |--------|  |           |          |      |      K "
3270 PRINT#1," |  |--|  |  |  |-CT-GND |          |      |    DIODE" 
3280 PRINT#1," |  |  |  |  |  |        |  GND     |      |      A "
3290 PRINT#1," |  | _|__|__|__|________|___|______|______|_     | "
3300 PRINT#1," |  | |9 10  13 12      14   11    15     16|     | "
3310 PRINT#1," |  | |                                     |     | "
3320 PRINT#1," |  | |        LM78S40                      |     | "
3330 PRINT#1," |  | |                                     |     | "
3340 PRINT#1," |  | |__8_____________________3___1___2____|     | "
3350 PRINT#1," |  |    |                     |                  | "
3360 PRINT#1," |  |-R2-|                    GND                 | "
3370 PRINT#1," |  |                                             | "
3380 PRINT#1," |  |----------R1------------------|--------------|-OUT"
3390 PRINT#1," G                                 CO"
3400 PRINT#1," N                                 |"
3410 PRINT#1," D                                GND"
3490 PRINT#1, CHR$(12)
3500 CLOSE#1 : GOTO 3830
3510 REM INDUCTOR DESIGN
3520  RETURN: PRINT:PRINT"THIS INDUCTOR DESIGN IS BASED ON AMIDON FERRITE TOROIDAL CORES"
3530 PRINT"AVAILABLE FROM TECH AMERICA. MATERIAL 77 IS AVAILABLE IN 4 SIZES:"
3540 PRINT".5 ODx.281 ID, .5 ODx.312 ID, .825 ODx.516ID, 1.142 ODx.75 ID "
3550 IF IPK<.6 THEN Q=1 :PRINT"Q=";Q
3560 IF IPK>=.6 THEN Q=2
3570 IF IL*VOUT=<2 THEN J=1
3580 IF IL*VOUT=<5 AND IL*VOUT>2 THEN J=2
3590 IF IL*VOUT=<18 AND IL*VOUT>5 THEN J=3
3600 IF IL*VOUT=<70 AND IL*VOUT>18 THEN J=4
3610 IF IL*VOUT>70 THEN PRINT"THIS DESIGN CANNOT EXCEED 70 WATTS"
3620 SIZE$(1)=".5x.281x.188" : CORE$(1)="900-6993" : AL(1)=1100 
3630 SIZE$(2)=".5x.312x.250" : CORE$(2)="900-6996" : AL(2)=1200 
3640 SIZE$(3)=".825x.516x.250" : CORE$(3)="900-6999" : AL(3)=1170 
3650 SIZE$(4)="1.142x.750x.295" : CORE$(4)="900-7002" : AL(4)=1270
3660 TURNS(1,1)=84:TURNS(1,2)=46:TURNS(2,1)=150:TURNS(2,2)=84
3670 TURNS(3,1)=356 : TURNS(3,2)=200:TURNS(4,1)=650:TURNS(4,2)=375
3680 N=1000!*SQR(L*1000!/AL(J))
3690 IF N<5 THEN 3720
3700 IF N>TURNS(J,Q) THEN J=J+1:GOTO 3680
3710 RETURN
3720 SIZE$(1)=".5x.281x.188" : CORE$(1)="900-6992" : AL(1)=68 
3730 SIZE$(2)=".5x.312x.250" : CORE$(2)="900-6995" : AL(2)=75 
3740 SIZE$(3)=".825x.516x.250" : CORE$(3)="900-6998" : AL(3)=73.3 
3750 SIZE$(4)="1.142x.750x.295" : CORE$(4)="900-7001" : AL(4)=79.3
3760 TURNS(1,1)=84:TURNS(1,2)=46:TURNS(2,1)=150:TURNS(2,2)=84
3770 TURNS(3,1)=356 : TURNS(3,2)=200:TURNS(4,1)=650:TURNS(4,2)=375
3780 N=1000!*SQR(L*1000!/AL(J))
3790 IF N>TURNS(J,Q) THEN J=J+1:GOTO 3780
3800 RETURN
3810 REM 78S40DES.BAS
3820 INPUT"PRESS ANY KEY TO EXIT";Y$
3830 END